Excel实例下载
  VBA  应用教程
    数据库SQL知识
设为首页
窗口(Window对象)基本操作应用示例
作者:fanjy | 来源:ExcelHomeBlog | 时间:2006-12-21 | 阅读权限:游客 | 会员币:0 | 【
Window对象代表一个窗口,约有48个属性和14个方法,能对窗口特性进行设置和操作。Window对象是Windows集合中的成员,对于Application对象来说,Windows集合包含该应用程序中的所有窗口;对于Workbook对象来说,Windows集合只包含指定工作簿中的窗口。下面介绍一些示例,以演示和说明Window对象及其属性和方法的运用。

示例02-01:激活窗口(Activate方法)
Sub SelectWindow()
  Dim iWin As Long, i As Long, bWin
  MsgBox "依次切换已打开的窗口"
  iWin = Windows.Count
  MsgBox “您已打开的窗口数量为:” & iWin
  For i = 1 To iWin
    Windows(i).Activate
    bWin = MsgBox("您激活了第 " & i & "个窗口,还要继续吗?", vbYesNo)
    If bWin = vbNo Then Exit Sub
  Next i
End Sub

示例02-02:窗口状态(WindowState属性)
[示例02-02-01]
Sub WindowStateTest()
  MsgBox "当前活动工作簿窗口将最小化"
  Windows(1).WindowState = xlMinimized
  MsgBox "当前活动工作簿窗口将恢复正常"
  Windows(1).WindowState = xlNormal
  MsgBox "当前活动工作簿窗口将最大化"
  Windows(1).WindowState = xlMaximized
End Sub
示例说明:使用WindowState属性可以返回或者设置窗口的状态。示例中,常量xlMinimized、xlNormal和xlMaximized分别代表窗口不同状态值,Windows(1)表示当前活动窗口。可以使用Windows(index)来返回单个的Window对象,其中的index为窗口的名称或编号,活动窗口总是Windows(1)。
[示例02-02-02]
Sub testWindow()
  '测试Excel应用程序窗口状态
  MsgBox "应用程序窗口将最大化"
  Application.WindowState = xlMaximized
  Call testWindowState
  MsgBox "应用程序窗口将恢复正常"
  Application.WindowState = xlNormal
  MsgBox "应用程序窗口已恢复正常"
    '测试活动工作簿窗口状态
    MsgBox "当前活动工作簿窗口将最小化"
    ActiveWindow.WindowState = xlMinimized
    Call testWindowState
    MsgBox "当前活动工作簿窗口将最大化"
    ActiveWindow.WindowState = xlMaximized
    Call testWindowState
    MsgBox "当前活动工作簿窗口将恢复正常"
    ActiveWindow.WindowState = xlNormal
    Call testWindowState
  MsgBox "应用程序窗口将最小化"
  Application.WindowState = xlMinimized
  Call testWindowState
End Sub
‘*********************************************************
Sub testWindowState()
  Select Case Application.WindowState
    Case xlMaximized: MsgBox "应用程序窗口已最大化"
    Case xlMinimized: MsgBox "应用程序窗口已最小化"
    Case xlNormal:
      Select Case ActiveWindow.WindowState
        Case xlMaximized: MsgBox "当前活动工作簿窗口已最大化"
        Case xlMinimized: MsgBox "当前活动工作簿窗口已最小化"
        Case xlNormal: MsgBox "当前活动工作簿窗口已恢复正常"
      End Select
  End Select
End Sub
示例说明:本示例有两个程序,其中testWindow()是主程序,调用子程序textWindowState(),演示了应用程序窗口和工作簿窗口的不同状态。当前活动窗口一般代表当前活动工作簿窗口,读者可以在VBE编辑器中按F8键逐语句运行testWindow()程序,观察Excel应用程序及工作簿窗口的不同状态。此外,在子程序中,还运用了嵌套的Select Case结构。
[示例02-02-03]
Sub SheetGradualGrow()
  Dim x As Integer
  With ActiveWindow
    .WindowState = xlNormal
    .Top = 1
    .Left = 1
    .Height = 50
    .Width = 50
    For x = 50 To Application.UsableHeight
      .Height = x
    Next x
    For x = 50 To Application.UsableWidth
      .Width = x
    Next x
    .WindowState = xlMaximized
  End With
End Sub
示例说明:本示例将动态演示工作簿窗口由小到大直至最大化的变化过程。在运行程序时,您可以将VBE窗口缩小,从而在工作簿中查看动态效果,也可以在Excel中选择菜单中的宏命令执行以查看效果。

示例02-03:切换显示工作表元素
[示例02-03-01]
Sub testDisplayHeading()
  MsgBox “切换显示/隐藏行列标号”
  ActiveWindow.DisplayHeadings = Not ActiveWindow.DisplayHeadings
End Sub
示例说明:本示例切换是否显示工作表中的行列标号。运行后,工作表中的行标号和列标号将消失;再次运行后,行列标号重新出现,如此反复。您也可以将该属性设置为False,以取消行列标号的显示,如ActiveWindow.DisplayHeadings = False;而将该属性设置为True,则显示行列标号。
[示例02-03-02]
Sub testDisplayGridline()
  MsgBox “切换显示/隐藏网格线”
  ActiveWindow.DisplayGridlines = Not ActiveWindow.DisplayGridlines
End Sub
示例说明:本示例切换是否显示工作表中的网格线。运行后,工作表中的网格线消失,再次运行后,网格线重新出现,如此反复。您也可以将该属性设置为False,以取消网格线显示,如ActiveWindow.DisplayGridlines = False;而将该属性设置为True,则显示网格线。
[示例02-03-03]
Sub DisplayHorizontalScrollBar()
  MsgBox “切换显示/隐藏水平滚动条”
  ActiveWindow.DisplayHorizontalScrollBar =  _
   Not ActiveWindow.DisplayHorizontalScrollBar
End Sub
示例说明:本示例切换是否显示工作表中的水平滚动条。运行后,工作表中的水平滚动条消失,再次运行后,水平滚动条重新出现,如此反复。您也可以将该属性设置为False,以取消水平滚动条,如ActiveWindow.DisplayHorizontalScrollBar = False;而将该属性设置为True,则显示水平滚动条。
同理,DisplayVerticalScrollBar属性将用来设置垂直滚动条。
[示例02-03-04]
Sub DisplayScrollBar()
  MsgBox "切换显示/隐藏水平和垂直滚动条"
  Application.DisplayScrollBars = Not (Application.DisplayScrollBars)
End Sub
示例说明:本示例切换是否显示工作表中的水平和垂直滚动条。运行后,工作表中的水平和垂直滚动条同时消失,再次运行后,水平和垂直滚动条重新出现,如此反复。您也可以将该属性设置为False,以取消水平和垂直滚动条显示,如Application.DisplayScrollBars= False;而将该属性设置为True,则显示水平和垂直滚动条。

示例02-04:显示公式(DisplayFormulas属性)
Sub DisplayFormula()
  MsgBox “显示工作表中包含公式的单元格中的公式”
  ActiveWindow.DisplayFormulas = True
End Sub
示例说明:本程序运行后,工作表中含有公式的单元格将显示公式而不是数值。若要显示数值,则将该属性设置为False,或者,如果工作表中的公式显示的是结果数值,则该属性为False。

示例02-05:显示/隐藏工作表标签(DisplayWorkbookTabs属性)
Sub testDisplayWorkbookTab()
  MsgBox “隐藏工作表标签”
  ActiveWindow.DisplayWorkbookTabs = False
End Sub
示例说明:本程序运行后,工作表标签消失。将该属性设置为True,重新显示工作表标签。

示例02-06:命名活动窗口(Caption属性)
Sub testCaption()
  MsgBox "当前活动工作簿窗口的名字是:" & ActiveWindow.Caption
  ActiveWorkbook.Windows(1).Caption = "我的工作簿"
  MsgBox "当前活动工作簿窗口的名字是:" & ActiveWindow.Caption
End Sub
示例说明:本程序运行后,显示当前活动工作簿窗口原先的名称(即工作簿窗口未处于最大化状态时,出现在窗口顶部标题栏中的文字),然后设置当前活动工作簿窗口名称,即使用语句ActiveWorkbook.Windows(1).Caption = "我的工作簿",最后显示当前活动工作簿窗口的新名称。改变窗口的标题并不会改变工作簿的名称。

示例02-07:移动窗口到指定位置(ScrollRow属性和ScrollColumn属性)
Sub testScroll()
  MsgBox “将当前窗口工作表左上角单元格移至第10行第3列”
  ActiveWindow.ScrollRow = 10
  ActiveWindow.ScrollColumn = 3
End Sub
示例说明:本程序运行后,当前活动窗口左上角单元格为第10行第3列。可以通过设置这两个属性来移动窗口到指定的位置,也可以返回指定窗格或窗口最左上面的行号或列号。

[NextPage] 示例02-08:调整窗口(EnableResize属性)
Sub testResize()
  MsgBox “设置窗口大小不可调整”
  ActiveWindow.EnableResize = False
End Sub
示例说明:测试本程序前,将当前工作簿窗口恢复为正常状态(即让工作簿标题可见),运行程序后,当前工作簿窗口将不能调整其大小,右上角的最小化最大化按钮将消失(即隐藏最大化和最小化按钮)。该属性设置为True,则能调整窗口大小。

示例02-09:拆分窗格
[示例02-09-01]
Sub SplitWindow1()
  Dim iRow As Long, iColumn As Long
  MsgBox "以活动单元格为基准拆分窗格"
  iRow = ActiveCell.Row
  iColumn = ActiveCell.Column
  With ActiveWindow
    .SplitColumn = iColumn
    .SplitRow = iRow
  End With
  MsgBox "恢复原来的窗口状态"
  ActiveWindow.Split = False
End Sub
[示例02-09-02]
Sub SplitWindow()
  Dim iRow As Long, iColumn As Long
  MsgBox "以活动单元格为基准拆分窗格"
  iRow = ActiveCell.Row
  iColumn = ActiveCell.Column
  With ActiveWindow
    .SplitColumn = iColumn
    .SplitRow = iRow
  End With
  MsgBox "恢复原来的窗口状态"
  ActiveWindow.SplitColumn = 0
  ActiveWindow.SplitRow = 0
End Sub
示例说明:本示例演示了以活动单元格为基准拆分窗格。如果指定窗口被拆分,则Split属性的值为True;设置该属性的值为False则取消窗格拆分。也可以设置SplitColumn属性和SplitRow属性的值来取消窗格拆分。

示例02-10:冻结窗格(FreezePanes属性)
Sub testFreezePane()
  MsgBox “冻结窗格”
  ActiveWindow.FreezePanes = True
End Sub
示例说明:运行本程序后,将会冻结活动单元格所在位置上方和左侧的单元格区域。将该属性的值设置为False,将取消冻结窗格。

示例02-11:设置网格线颜色(GridlineColor属性和GridlineColorIndex属性)
Sub setGridlineColor()
  Dim iColor As Long
  iColor=ActiveWindow.GridlineColor
  MsgBox "将活动窗口的网格线颜色设为红色"
  ActiveWindow.GridlineColor = RGB(255, 0, 0)
  MsgBox "将活动窗口的网格线颜色设为蓝色"
  ActiveWindow.GridlineColorIndex = 5
  MsgBox “恢复为原来的网格线颜色”
  ActiveWindow.GridlineColorIndex=iColor
End Sub
示例说明:运行程序后,当前工作表窗口网格线将被设置为红色。其中,GridlineColorIndex属性可以用于返回或设置网格线的颜色,下面给出了默认调色板中颜色的编号值:

[小结]ActiveWindow属性返回当前激活的工作簿窗口,可以用来设置工作表中的元素,也可以显示特定的单元格,或者用来调整窗口的显示比例,以及设置窗口。
示例02-12:设置工作表标签区域宽度和水平滚动条宽度比例(TabRatio属性)
Sub test()
  MsgBox "设置工作表标签区域宽度为水平滚动条宽度的一半"
  ActiveWindow.TabRatio = 0.5
End Sub
示例说明:TabRatio属性返回或设置工作簿中工作表标签区域的宽度与窗口水平滚动条的宽度比例(可为0到1之间的数字;默认值为0.6)。您可以改变上面程序中的数值进行测试。

示例02-13:设置激活窗口时运行的程序(OnWindow属性)
Sub testRunProcedure()
  ThisWorkbook.Windows(1).OnWindow = "test"
End Sub
‘*********************************************************
Sub test()
  MsgBox "您可以使用本窗口了!"
End Sub
示例说明:本示例包括两个程序,主程序为testRunProcedure(),运行后,每当激活该窗口时,将会运行test()程序。其中,OnWindow属性返回或设置每当激活一个窗口时要运行的过程的名称,如本例中的test()程序。

示例02-14:获取指定窗口单元格区域地址(RangeSelection属性)
Sub testRangeSelection()
  MsgBox "显示所选单元格地址"
  MsgBox ActiveWindow.RangeSelection.Address
End Sub
示例说明:本示例返回当前窗口中所选单元格区域的地址。RangeSelection属性返回指定窗口的工作表中的选定单元格(即使指定工作表中有图形对象处于活动状态,或者已选定图形对象,仍返回在图形对象被选定之前选定的单元格区域,这是该属性与Selection属性的区别)。

[NextPage] 示例02-15:返回指定窗口中所选择的工作表(SelectedSheets属性)
Sub testSelectedSheet()
  Dim sh As Worksheet
  For Each sh In ActiveWorkbook.Windows(1).SelectedSheets
    MsgBox "工作表" & sh.Name & "被选择"
  Next
End Sub
示例说明:SelectedSheets属性返回代表指定窗口中的所有选定工作表的集合。本示例中,如果您同时选择了活动工作簿中的工作表Sheet1和Sheet2,那么运行程序后,将会显示相应工作表被选择的信息。

示例02-16:排列窗口(Arrange方法)
Sub testArrangeWindows()
  MsgBox "请确保应用程序至少含有两个工作簿,这样才能看出效果"
  MsgBox “窗口将平铺显示”
  Windows.Arrange ArrangeStyle:=xlArrangeStyleTiled
  MsgBox “窗口将层叠显示”
  Windows.Arrange ArrangeStyle:=xlArrangeStyleCascade
  MsgBox “窗口将水平排列显示”
  Windows.Arrange ArrangeStyle:=xlArrangeStyleHorizontal
  MsgBox “窗口将垂直并排排列显示”
  Windows.Arrange ArrangeStyle:=xlArrangeStyleVertical
End Sub
示例说明:运行本程序后,将平铺应用程序中的所有窗口。Arrange方法用于对屏幕上的窗口进行排列,其语法为expression.Arrange(ArrangeStyle, ActiveWorkbook, SyncHorizontal, SyncVertical),所有的参数均为可选参数。其中,参数ArrangeStyle代表排列样式,可为以下常量:常量xlArrangeStyleTiled为缺省值,表示将平铺窗口;常量xlArrangeStyleCascade表示将窗口进行层叠;常量xlArrangeStyleHorizontal表示将水平排列所有窗口;常量xlArrangeStyleVertical表示将垂直并排排列所有窗口。您可以在上面的程序中测试这些常量,以体验效果。将参数ActiveWorkbook设置为True,则只对当前工作簿的可见窗口进行排列。如果为False,则对所有窗口进行排列。默认值为 False。设置参数SyncHorizontal为True,在水平滚动时同步滚动当前工作簿的所有窗口;如果为 False,则不同步滚动。设置参数SyncVertical为True,则在垂直滚动时同步滚动当前工作簿的所有窗口;如果为 False,则不同步滚动,默认值为 False。如果参数ActiveWorkbook为False或者省略,则参数SyncHorizontal和SyncVertical被忽略。

示例02-17:窗口尺寸(UsableHeight、UsableWidth、Height、Width属性)
Sub testActiveWindowSize()
 MsgBox "当前窗口可用区域的高度为:" & ActiveWindow.UsableHeight
   MsgBox "当前窗口的高度为:" & ActiveWindow.Height
   MsgBox "当前窗口可用区域的宽度为:" & ActiveWindow.UsableWidth
   MsgBox "当前窗口的宽度为:" & ActiveWindow.Width
End Sub

示例02-18:水平排列两个窗口
Sub testWindowArrange()
  Dim ah As Long, aw As Long
  Windows.Arrange xlArrangeStyleTiled
  ah = Windows(1).Height
  aw = Windows(1).Width + Windows(2).Width
  With Windows(1)
    .Width = aw
    .Height = ah / 2
    .Left = 0
  End With
  With Windows(2)
    .Width = aw
    .Height = ah / 2
    .Top = ah / 2
    .Left = 0
  End With
End Sub
示例说明:在运行本示例前,保证只打开了两个工作簿窗口。运行本示例后,将水平排列第一个窗口和第二个窗口,即每个窗口占用可使用的垂直空间的一半,占用所有水平空间。其中,Top属性表示从窗口顶端到可用区域顶端的距离,无法对最大化的窗口设置本属性;Left属性表示使用区域的左边界至窗口左边界的距离,如果窗口已最大化,则会返回一个负数;如果该属性被设置为0,则窗口的主边框刚好在屏幕上可见。

示例02-19:改变窗口的高度和宽度
Sub ChangeHeightAndWidth()
  Dim iWinHeight As Long, iWinWidth As Long
  ActiveWindow.WindowState = xlNormal
  MsgBox "将当前窗口的高度和宽度各减一半"
  iWinHeight = ActiveWindow.Height
  iWinWidth = ActiveWindow.Width
  ActiveWindow.Height = iWinHeight / 2
  ActiveWindow.Width = iWinWidth / 2
  MsgBox "恢复原窗口大小"
  ActiveWindow.Height = iWinHeight
  ActiveWindow.Width = iWinWidth
End Sub
示例说明:Height属性和Width属性必须在窗口处于正常显示状态(即不是最大化或最小化状态)时使用,否则会出错。

示例02-20:移动窗口
Sub SetWindowPosition()
  Dim iTop As Long, iLeft As Long
  MsgBox "将当前窗口向下移60,向右移90"
  ActiveWindow.WindowState = xlNormal
  iTop = ActiveWindow.Top
  iLeft = ActiveWindow.Left
  ActiveWindow.Top = iTop + 60
  ActiveWindow.Left = iLeft + 90
  MsgBox "恢复原来窗口的位置"
  ActiveWindow.Top = iTop
  ActiveWindow.Left = iLeft
End Sub
示例说明:Top属性和Left属性必须在窗口处于正常显示状态(即不是最大化或最小化状态)时使用,否则会出错。

示例02-21:并排比较窗口
Sub testCompare()
  MsgBox "与工作簿Book2进行并排比较"
  Windows.CompareSideBySideWith "Book2"
  MsgBox "启动窗口滚动功能,使两个窗口同时滚动"
  Windows.SyncScrollingSideBySide = True
  MsgBox "将工作簿Book2最小化"
  Windows("Book2").WindowState = xlMinimized
  MsgBox "重置并排比较显示,恢复并排比较"
  Windows.ResetPositionsSideBySide
  MsgBox "关闭并排比较"
  ActiveWorkbook.Windows.BreakSideBySide
End Sub
示例说明:在运行本示例前,确保在本窗口外还打开了一个名为Book2的窗口,或者您打开了一个其它命名的窗口,相应将上面程序中的Book2更换为您的窗口名。CompareSideBySideWith方法将以并排模式打开两个窗口,其中一个是当前活动窗口,另一个就是该方法所指定的窗口,如本例中的Book2。SyncScrollingSideBySide属性设置是否将两个窗口的滚动保持同步,如果为True,在对文档进行并排比较的同时启用窗口内容的滚动功能。若为False,则在对文档进行并排比较的同时禁用窗口内容的滚动功能。ResetPositionsSideBySide方法重置正在进行并排比较的两个工作表窗口的位置,例如,如果用户将正在进行比较的两个工作表窗口中的其中一个窗框最小化或最大化,就可以使用ResetPositionsSideBySide方法重置显示,以便这两个窗口再次并排显示。BreakSideBySide方法用来关闭并排比较。

[NextPage] 示例02-22:返回或设置窗口中显示的视图(View属性)
Sub testView()
  MsgBox "将视图切换为分页预览"
  ActiveWindow.View = xlPageBreakPreview
  MsgBox "窗口视图为:" & ActiveWindow.View
  MsgBox "将视图恢复正常"
  ActiveWindow.View = xlNormalView
  MsgBox "窗口视图为:" & ActiveWindow.View
End Sub

示例02-23:返回窗口中可见单元格区域(VisibleRange属性)
Sub testVisibleRange()
  MsgBox "当前窗口中共有" & Windows(1).VisibleRange.Cells.Count & "个单元格可见"
End Sub
示例说明:如果窗口中有部分行列的单元格可见,也包括在可见单元格区域中。

示例02-24:创建窗口(NewWindow方法)
Sub testNewWindow()
  MsgBox "为活动窗口创建一个副本"
  ActiveWindow.NewWindow
  MsgBox "所创建窗口的窗口号为" & ActiveWindow.WindowNumber
End Sub
示例说明:本示例中,NewWindow方法为指定窗口(本例中为当前活动窗口)创建一个副本,然后显示该副本窗口的窗口号。注意,窗口号与窗口索引(Index属性)的不同,例如名称为“Book1.xls:2”的窗口,其窗口号为2,而窗口索引为该窗口在Windows集合中的位置,可以为窗口名称或编号。

示例02-25:设置窗口大小(Zoom属性)
Sub testWindowDisplaySize()
  MsgBox "将窗口大小设置为与选定区域相适应的大小"
  ActiveWindow.Zoom = True
  MsgBox "以双倍大小显示窗口"
  ActiveWindow.Zoom = 200
  MsgBox "以正常大小显示窗口"
  ActiveWindow.Zoom = 100
End Sub
示例说明:Zoom属性将以百分数的形式(100表示正常大小,200表示双倍大小,以此类推)返回或设置窗口的显示大小。如果本属性为 True,则可将窗口大小设置成与当前选定区域相适应的大小。本功能仅对窗口中当前的活动工作表起作用,若要对其他工作表使用本属性,必须先激活该工作表。

示例02-26:激活窗口(ActivateNext方法和ActivatePrevious方法)
[示例02-26-01]
Sub testActivateWindow1()
  MsgBox "若已打开Book1.xls、Book2.xls和Book3.xls三个工作簿且Book1.xls为当前窗口" & Chr(10) & "则按Book3.xls-Book2.xls-Book1.xls依次激活窗口"
    ActiveWindow.ActivateNext
    MsgBox "激活工作簿:" & Windows(1).Caption
    ActiveWindow.ActivateNext
    MsgBox "激活工作簿:" & Windows(1).Caption
    ActiveWindow.ActivateNext
    MsgBox "激活工作簿:" & Windows(1).Caption
End Sub
[示例02-26-02]
Sub testActivateWindow2()
   MsgBox "若已打开Book1.xls、Book2.xls和Book3.xls三个工作簿且Book1.xls为当前窗口" & Chr(10) & "则按Book2.xls-Book3.xls-Book1.xls依次激活窗口"
    ActiveWindow.ActivatePrevious
    MsgBox "激活工作簿:" & Windows(1).Caption
    ActiveWindow.ActivatePrevious
    MsgBox "激活工作簿:" & Windows(1).Caption
    ActiveWindow.ActivatePrevious
    MsgBox "激活工作簿:" & Windows(1).Caption
End Sub

示例02-27:滚动窗口(LargeScroll方法和SmallScroll方法)
[示例02-27-01]
Sub testScroll1()
  MsgBox "将当前窗口向下滚动3页并向右滚动1页"
  ActiveWindow.LargeScroll Down:=3, ToRight:=1
End Sub
示例说明:LargeScroll方法将按页滚动窗口的内容,其语法为expression.LargeScroll(Down, Up, ToRight, ToLeft),带有4个可选的参数,其中参数Down表示将窗口内容向下滚动的页数;参数Up表示将窗口内容向上滚动的页数;参数ToRight表示将窗口内容向右滚动的页数;参数ToLeft表示将窗口内容向左滚动的页数。如果同时指定了Down和Up,窗口内容上下方向滚动的页数由这两个参数的差决定,例如,如果Down为3,Up为6,则窗口向上滚动三页。如果同时指定了ToLeft和ToRight,窗口内容左右方向滚动的页数由这两个参数的差决定,例如,如果ToLeft为3,ToRight为 6,则窗口向右滚动三页。所有这四个参数都可以使用负数。
[示例02-27-02]
Sub testScroll2()
  MsgBox "将当前活动窗口向下滚动3行"
  ActiveWindow.SmallScroll down:=3
End Sub
示例说明:SmallScroll方法按行或列滚动窗口,其语法为expression.SmallScroll(Down, Up, ToRight, ToLeft),带有4个可选的参数,其中参数Down表示将窗口内容向下滚动的行数;参数Up表示将窗口内容向上滚动的列数;参数ToRight表示将窗口内容向右滚动的列数;参数ToLeft表示将窗口内容向左滚动的列数。如果同时指定了Down和Up,则窗口内容滚动的行数由这两个参数的差值决定,例如,如果Down为3,Up为6,则窗口内容向上滚动三行。如果同时指定了ToLeft和ToRight,则窗口内容滚动的列数由这两个参数的差值决定,例如,如果ToLeft为3,ToRight为 6,则窗口内容向右滚动三列。以上四个参数均可取负值。

示例02-28:测试所选单元格宽度和高度
Sub testWidthOrHeight()
  Dim lWinWidth As Long, lWinHeight As Long
  With ActiveWindow
    lWinWidth = .PointsToScreenPixelsX(.Selection.Width)
    lWinHeight = .PointsToScreenPixelsY(.Selection.Height)
  End With
  MsgBox "当前选定单元格宽度为:" & lWinWidth & Chr(10) & _
     "当前选定单元格高度为:" & lWinHeight
End Sub

示例02-29:关闭窗口(Close方法)
Sub CloseWindow()
  MsgBox "关闭当前窗口"
  ActiveWindow.Close
End Sub
示例说明:本示例运行后,将关闭当前窗口。如果当前窗口未保存,则会弹出询问是否保存的消息框供选择。
文章录入:admin | 浏览次数:
相关评论(以下网友评论只代表其个人观点,不代表Excel吧的观点或立场)
相关信息

关于本站 | 留言本站 | 友情连接 | 后台管理
Copyright © 2005 - 2008 Excel吧 Inc. All Rights Reserved.
HxCms Ver9.0  闽ICP备06001689号
关闭此窗口